GM Poisoning

Joined: 12 Nov 2008 Posts: 20

I didn't write this script but it works perfect with this shard.

Just copy and paste into a new file in EasyUO.

Code:

;========================================
; Script Name: Noxious Poisoning
; Author: Dark Noxious, based on Vision's Poisoning Script
; Version: 2.0
; Client Tested with: 4.0.2a
; EUO version tested with: 1.41
; Shard OSI / FS: OSI
; Revision Date: 03.10.04
; Public Release: 03.08.04
; Purpose: Gain poisoning skill from 0.0 - 100.0
;========================================
;
; ============ New Version History ============
; Version 2.0 is really revamped! Added features include: automatically choosing the
; correct level of poison for you by setting up seperate secure containers for each level,
; showing your gains and number of kegs used in the title bar, and a new super-easy
; interactive setup! The script should now work with 800x600 resolution as well. Note, a
; change is that now you need three bags inside your backpack: fishbag, kegbag and emptybag.
;
; Version 1.0. Script released to the public in working condition. Must have client in
; 1024x768 resolution to work correctly.

; ============ Usage ============
; This script will train your poisoning skill by unstacking fishsteaks,
; using poison, and restacking the fishsteaks. This gives a new ID
; to the fish every time, so that you're constantly poisoning on new
; targets. Furthermore, if you "make a grave mistake" and become
; poisoned, the script will make a Greater Cure potion and drink it.
; Then it checks your health and uses bandaids to heal you if necessary.
; After you're in the all clear, it will go back to poisoning.
;
; ============ Instructions for Setup ============
; You will need three bags inside your backpack. One should contain
; a stack of fishsteaks, another should contain a keg of the level of
; poison you need to train on, and the last should be empty.
; For purposes of skill gain, train from
; 0-40 on Lesser Poison, from 40-70 on Regular Poison, and from
; 70-100 on Greater Poison. You will also need at least two secure containers.
; One should be empty to put the used kegs into, and the other(s) should
; contain a good amount of kegs for you to use while training. If you use more than
; one secure container for full kegs, divide the kegs so that the correct level of poison
; is in it's respective secure container. The script will choose which level of poison to use.
; You will also need to have a keg of Greater Cure locked down within
; reach of your character, and will need to have several bottles inside your
; backpack. Start with one Greater Cure potion in your backpack, that way if
; your keg runs dry you will at least cure the last of the poison before the script
; halts. This script will also heal you, and you need bandaids in your
; backpack as well. I may change the script later so that healing with
; bandages becomes optional.
; Set the variables below if you're not using the interactive setup, and hit play.
; =========================================
InitEvents
; ============ Customize These Variables ============
; Only need to set these variables if you're not using the interactive setup
set %backpack XXXXXXX
set %fishbag XXXXXXX
set %poisonbag XXXXXXX
set %emptybag XXXXXXX
set %lessercrate XXXXXXX
set %regularcrate XXXXXXX
set %greatercrate XXXXXXX
set %emptycrate XXXXXXX
set %curekeg XXXXXXX
; ============ Variable Information ============
; %backpack - Your backpack ID
; %fishbag - Set to the contid of the bag with the fishsteaks inside
; %poisonbag - Set to the contid of the bag with the poison keg inside
; %lessercrate - Set to the contid of the secure with full lesser kegs inside
; %regularcrate - Set to the contid of the secure with full regular kegs inside
; %greatercrate - Set to the contid of the secure with full greater kegs inside
; %emptycrate - Set to the contid of the secure to put the empty kegs inside
; %curekeg - Set to the ID of your Greater Cure keg that is locked down near you
; =========================================
set %ppot AVF
set %fish HND
set %keg QMJ
set %cpot NUF
set %bandaid ZLF
set %healtime 10s
; ============ Other Variable Information ============
; %ppot - Don't need to change, unless the ID of the poison potion changes
; %fish - Don't need to change, unless the ID of the dish steak or apple changes
; %keg - Don't need to change, unless the ID of the keg changes
; %cpot - Don't need to change, unless the ID of the cure potion changes
; %bandaid - Don't need to change, unless the ID of the bandage changes
; %healtime - Don't need to change. Sets an amount of time to heal and pause for hiding skill
; =============================================
;
; ============ Excess Variables for Statistics ============
chooseskill poisoning
set %startingskill #skill
set %lesserkegsused 0
set %regularkegsused 0
set %greaterkegsused 0
if #skill < 400
{
set %lesserkegsused 1
}
if #skill < 500
{
set %regularkegsused 1
}
if #skill > 699
{
set %greaterkegsused 1
}
; ============ Main Script - Don't Edit Beyond Here ============
;
display ok Welcome to Noxious Poisoning 101!$You need: Three bags inside your backpack. Bag one - stack of fishsteaks; Bag two - poison keg of correct level;$Bag three - empty. You also need a stack of bottles in your backpack, some bandages and one greater cure potion.
display ok Around your character you will need secure containers for each $level of poison (full kegs stored inside) that you will use.$You will also need an empty secure container to store the empty $kegs in and a greater cure keg locked down near you.
display ok If you are only going to use one secure container for full kegs, just$target it three times in the interactive setup. Otherwise you$can just disregard setting each of the other secures in the manual$setup (i.e. if your skill is already over 70)
wait 10
display yesno Use Interactive Setup?
if #dispres = yes
{
set %interactive yes
wait 1s
}
if #dispres = no
{
set %interactive no
wait 1s
}

if %interactive = yes
gosub interactivesetup

setupdone:

display yesno Would you like to show some statistics in your UO titlebar?$Note: Running UOAssist may cause statistics to not display properly.
if #dispres = yes
set %titlebar yes
if #dispres = no
set %titlebar no

Event Macro 31 0
wait 10

wait 10
Event Macro 8 1
wait 10
contpos 795 0
wait 20

event macro 8 2
wait 10
contpos 795 330
wait 20

event macro 8 7
wait 10
contpos 625 205
wait 20

set #LOBJECTID %fishbag
event macro 17 0
wait 10
contpos 625 405
wait 20

set #LOBJECTID %poisonbag
event macro 17 0
wait 10
contpos 430 405
wait 20

set #LOBJECTID %emptybag
event macro 17 0
wait 10
contpos 235 405
wait 20

Loop:
if %titlebar = yes
{
gosub setstatsintitlebar
}
gosub Poison
gosub Cure
gosub Heal

goto Loop

; ============= Poison Subroutine ============
sub Poison

finditem %fish C_ , %fishbag
Set %FSfindid #findid
event drag %FSfindid
wait 20
msg 1$
wait 10
finditem %emptybag
set #FindMod 20_10
Click #FindX #FindY p
wait 20

Finditem %keg C_ , %poisonbag
if #findkind = 0
{
Finditem %keg C_ , %poisonbag
Set #FindMod 10_10
Click #FindX #FindY d
wait 40

scanJournal 1
if keg_is_empty in #journal
   {
   gosub Kegreplacer
   }
deleteJournal
wait 20

event macro 13 30
wait 30

finditem %ppot C_ , %backpack
set #LTARGETID #findid
set #LTARGETKIND 1
event macro 22 0
wait 30

finditem %fish C_ , %emptybag
set #LTARGETID #findid
set #LTARGETKIND 1
event macro 22 0
wait 50

finditem %fish C_ , %emptybag
set %SFfindid #findid
event drag %SFfindid
wait 10
msg $
wait 10

finditem %fishbag
set #FindMod 20_10
Click #FindX #FindY p
wait 30
}
return

; ============ Cure Subroutine ============
sub Cure

if C in #charstatus
{
finditem %curekeg
Set #LOBJECTID #findid
event macro 17 0
wait 20

finditem %cpot
Set #LOBJECTID #findid
event macro 17 0
wait 20

scanjournal 10
if is_empty in #journal
   {
   display ok Your cure keg is empty! $ Used safety cure potion.
   halt
   }
deleteJournal
}
return

; ============Heal Subroutine============
sub Heal

if #hits < #MaxHits
{
finditem %bandaid
if #findkind = -1
   {
   ;display ok Out of bandages. Pausing for safety.
   ;pause
   }
Set #LOBJECTID #findid
event macro 17 0
target 3s
event Macro 23 0
wait 40
event Macro 13 21
wait %healtime
gosub Heal
}
return

; ============ Replace Empty Kegs Subroutine ============

sub Kegreplacer

set #LOBJECTID %emptycrate
event macro 17 0
wait 20
contpos 0 0
wait 20

Finditem %keg C_ , %poisonbag
Set %emptykegid #findid
event drag %emptykegid
wait 10
click 70 70 p
wait 20

if #skill < 400
{
set #LOBJECTID %lessercrate
event macro 17 0
wait 20
contpos 230 0
wait 20

Finditem %keg C_ , %lessercrate
if #findkind = 0
{
Finditem %keg C_ , %lessercrate
Set %FKfindid #findid
event drag %FKfindid
wait 10
Finditem %poisonbag
Set #FindMod 20_10
Click #FindX #FindY
wait 10

wait 10
click 90 90 r
wait 10
click 300 90 r
wait 10

Finditem %keg C_ , %poisonbag
Set #FindMod 10_10
Click #FindX #FindY d
wait 20

set %lesserkegsused %lesserkegsused + 1

return
}
display ok No kegs available!
halt
}

if #skill < 700
{
set #LOBJECTID %regularcrate
event macro 17 0
wait 20
contpos 230 0
wait 20

Finditem %keg C_ , %regularcrate
if #findkind = 0
{
Finditem %keg C_ , %regularcrate
Set %FKfindid #findid
event drag %FKfindid
wait 10
Finditem %poisonbag
Set #FindMod 20_10
Click #FindX #FindY
wait 10

wait 10
click 90 90 r
wait 10
click 300 90 r
wait 10

Finditem %keg C_ , %poisonbag
Set #FindMod 10_10
Click #FindX #FindY d
wait 20

set %regularkegsused %regularkegsused + 1

return
}
display ok No kegs available!
halt
}

if #skill > 699
{
set #LOBJECTID %greatercrate
event macro 17 0
wait 20
contpos 230 0
wait 20

Finditem %keg C_ , %greatercrate
if #findkind = 0
{
Finditem %keg C_ , %greatercrate
Set %FKfindid #findid
event drag %FKfindid
wait 10
Finditem %poisonbag
Set #FindMod 20_10
Click #FindX #FindY
wait 10

wait 10
click 90 90 r
wait 10
click 300 90 r
wait 10

Finditem %keg C_ , %poisonbag
Set #FindMod 10_10
Click #FindX #FindY d
wait 20

set %greaterkegsused %greaterkegsused + 1

return
}
display ok No kegs available!
halt
}
; ============ Interactive Setup Subroutine ============
sub interactivesetup

set %backpack N/A
set %fishbag N/A
set %poisonbag N/A
set %emptybag N/A
set %lessercrate N/A
set %regularcrate N/A
set %greatercrate N/A
set %emptycrate N/A
set %curekeg N/A

event macro 8 7
wait 10
set %backpack #contid

set #targcurs 1
display ok Please target the bag with the fishsteaks
waitforfishbag:
if #targcurs = 1
goto waitforfishbag
set %fishbag #ltargetid
wait 10

set #targcurs 1
display ok Please target the bag with the poison keg
waitforpoisonbag:
if #targcurs = 1
goto waitforpoisonbag
set %poisonbag #ltargetid
wait 10

set #targcurs 1
display ok Please target the empty bag
waitforemptybag:
if #targcurs = 1
goto waitforemptybag
set %emptybag #ltargetid
wait 10

set #targcurs 1
display ok Please target the secure container with full lesser kegs
waitforlessercrate:
if #targcurs = 1
goto waitforlessercrate
set %lessercrate #ltargetid
wait 10

set #targcurs 1
display ok Please target the secure container with full regular kegs
waitforregularcrate:
if #targcurs = 1
goto waitforregularcrate
set %regularcrate #ltargetid
wait 10

set #targcurs 1
display ok Please target the secure container with full greater kegs
waitforgreatercrate:
if #targcurs = 1
goto waitforgreatercrate
set %greatercrate #ltargetid
wait 10

set #targcurs 1
display ok Please target the empty secure container to store empty kegs
waitforemptycrate:
if #targcurs = 1
goto waitforemptycrate
set %emptycrate #ltargetid
wait 10

set #targcurs 1
display ok Please target your Greater Cure keg that's locked down near you.
waitforcurekeg:
if #targcurs = 1
goto waitforcurekeg
set %curekeg #ltargetid
wait 10

display yesno Are your settings correct?
if #dispres = no
goto interactivesetup
if #dispres = yes
goto setupdone

; ============ Statistics in Titlebar Subroutine ============
sub setstatsintitlebar

chooseskill poisoning
set %wholeskill #skill / 10
set %tenthskill #skill % 10
set %deltawhole ( #skill - %startingskill ) / 10
set %deltatenth ( #skill - %startingskill ) % 10
set %skill %wholeskill , . . %tenthskill
set %deltaskill %deltawhole , . . %deltatenth
setuotitle Ultima Online - #charname ( #shard ) | Poisoning : %skill - Gain : %deltaskill | Kegs Used - Greater : %greaterkegsused - Regular : %regularkegsused - Lesser : %lesserkegsused

return

; ============ End of Script ============

Posted: Sat Apr 25, 2009 2:08 pm

Sweet, thanks Kas

I was getting about ready to work on Poisoning

Joined: 12 Nov 2008 Posts: 20

Just follow those directions and you are good to go =)